全部显示

CreateEventProc 方法

CreateEventProc 方法在类模块中创建一个事件过程。它返回一个 Long 型值来标识事件过程首行的行号。Long 型。

expression   必需。返回“Applies To”列表中的一个对象的表达式。

EventName  必需 String 型。字符串表达式，用于确定事件的名称。

ObjectName  必需 String 型。含有由 eventname 参数所指定事件的对象。可以是 Form、Report 或 Control 对象，窗体节或报表节，也可以是类模块。

说明

CreateEventProc 方法为指定对象的事件过程创建代码承接模块。例如，可以使用该方法为窗体上的命令按钮创建 Click 事件过程。Microsoft Access 在命令按钮所在窗体的相关模块中创建 Click 事件过程。

如果使用 CreateEventProc 方法创建了事件过程代码承接模块，则可以使用 Module 对象的其他方法为过程添加代码行。例如，可以使用 InsertLines 方法插入一行代码。

示例

下面的示例将创建新窗体、添加命令按钮并为命令按钮创建 Click 事件过程：

Function ClickEventProc() As Boolean
    Dim frm As Form, ctl As Control, mdl As Module
    Dim lngReturn As Long

    On Error GoTo Error_ClickEventProc
    ' Create new form.
    Set frm = CreateForm
    ' Create command button on form.
    Set ctl = CreateControl(frm.Name, acCommandButton, , , , _
         1000, 1000)
    ctl.Caption = "Click here"
    ' Return reference to form module.
    Set mdl = frm.Module
    ' Add event procedure.
    lngReturn = mdl.CreateEventProc("Click", ctl.Name)
    ' Insert text into body of procedure.
    mdl.InsertLines lngReturn + 1, vbTab & "MsgBox ""Way cool!"""
    ClickEventProc = True

Exit_ClickEventProc:
    Exit Function

Error_ClickEventProc:
    MsgBox Err & " :" & Err.Description
    ClickEventProc = False
    Resume Exit_ClickEventProc
End Function