AddIn 对象

代表已安装或尚未安装的单个加载宏。AddIn 对象是 AddIns 集合的成员。无论这些加载宏是否已经安装，AddIn 集合包含 Microsoft Excel 的所有可用加载宏的列表。此列表相应于“工具”菜单中的“加载宏”对话框内显示的加载宏列表。

Addin 对象的的用法

可用 AddIns(index) 返回单个 AddIn 对象，其中 index 为加载宏标题或编号。下例安装“分析工具库”加载宏。

AddIns("analysis toolpak").Installed = True

请勿混淆加载宏标题（出现在“加载宏”对话框中的标题）与加载宏名称（加载宏的文件名）。必须严格按照“加载宏”对话框中的标题书写加载宏标题，但不必匹配大小写。

加载宏编号代表加载宏在“加载宏”对话框内“可用加载宏”列表框中的位置。下例创建可用加载宏的指定属性的列表。

With Worksheets("sheet1")
    .Rows(1).Font.Bold = True
    .Range("a1:d1").Value = _
        Array("Name", "Full Name", "Title", "Installed")
    For i = 1 To AddIns.Count
        .Cells(i + 1, 1) = AddIns(i).Name
        .Cells(i + 1, 2) = AddIns(i).FullName
        .Cells(i + 1, 3) = AddIns(i).Title
        .Cells(i + 1, 4) = AddIns(i).Installed
    Next
    .Range("a1").CurrentRegion.Columns.AutoFit
End With

说明

Add 方法将加载宏添加到当前加载宏列表中，但并不安装该加载宏。可将该加载宏的 Installed 属性设置为 True 以安装该加载宏。若要安装未出现在当前加载宏列表中的加载宏，必须首先使用 Add 方法，然后设置 Installed 属性。这可用一个步骤完成，如下例所示（注意，Add 方法使用的是加载宏的名称而非标题）。

AddIns.Add("generic.xll").Installed = True

可用 Workbooks(index) （其中 index 为加载宏文件名而非标题）返回对某工作簿的引用，该工作簿相应于某一已加载的加载宏。因为加载宏并不像常规工作簿那样出现在 Workbooks 集合中，所以必须使用其文件名来指定。本示例将变量 wb 设置为“Myaddin.xla”的工作簿。

Set wb = Workbooks("myaddin.xla")

下例将变量 wb 设置为“分析工具库”加载宏所在的工作簿。

Set wb = Workbooks(AddIns("analysis toolpak").Name)

如果 Installed 属性为 True，但调用加载宏中的函数仍旧失效，那么可能并未真正地加载了该加载宏。这是因为 Addin 对象代表了加载宏的存在及安装状态，但并不代表加载宏工作簿中的实际内容。为保证已安装的加载宏被调入，应当打开该加载宏工作簿。下例中，如果加载宏“My Addin”未出现在 Workbooks 集合中，就打开该加载宏。

On Error Resume Next    ' turn off error checking
Set wbMyAddin = Workbooks(Addins("My Addin").Name)
lastError = Err
On Error Goto 0        ' restore error checking
If lastError <> 0 Then
    ' the add-in workbook isn't currently open. Manually open it.
    Set wbMyAddin = Workbooks.Open(Addins("My Addin").FullName)
End If