Effect 对象

Sequence Effect 多个对象

代表有关幻灯片动画的计时信息。

使用 Effect 对象

使用 AddEffect 方法添加一个效果。本示例在当前演示文稿的第一张幻灯片中添加一个形状，并为该形状添加一种效果和一个动作。

Sub NewShapeAndEffect()
    Dim shpStar As Shape
    Dim sldOne As Slide
    Dim effNew As Effect

    Set sldOne = ActivePresentation.Slides(1)
    Set shpStar = sldOne.Shapes.AddShape(Type:=msoShape5pointStar, _
        Left:=150, Top:=72, Width:=400, Height:=400)
    Set effNew = sldOne.TimeLine.MainSequence.AddEffect(Shape:=shpStar, _
        EffectId:=msoAnimEffectStretchy, Trigger:=msoAnimTriggerAfterPrevious)
    With effNew
        With .Behaviors.Add(msoAnimTypeScale).ScaleEffect
            .FromX = 75
            .FromY = 75
            .ToX = 0
            .ToY = 0
        End With
        .Timing.AutoReverse = msoTrue
    End With
End Sub

若要引用现有的 Effect 对象，请使用 MainSequence(index)，其中 index 是 Effect 对象在 Sequence 集合中的编号。本示例更改第一个序列的效果并为该效果指定动作。

Sub ChangeEffect()
    With ActivePresentation.Slides(1).TimeLine _
        .MainSequence(1)
        .EffectType = msoAnimEffectSpin
        With .Behaviors(1).RotationEffect
            .From = 100
            .To = 360
            .By = 5
        End With
    End With
End Sub

不管幻灯片是否有动画，每张幻灯片中至少有一个 Effect 对象。