Delete 方法

删除一个或多个表格单元格并可选择控制如何移动剩余的单元格。

expression.Delete(ShiftCells)

expression 必需。该表达式返回以上一个对象。

ShiftCells Variant 类型，可选。剩余单元格移动的方向。可以是任意 WdDeleteCells 常量。如果忽略，最后删除的单元格的右侧单元格向左移动。

WdDeleteCells 可以是下列 WdDeleteCells 常量之一：

wdDeleteCellsEntireColumn

wdDeleteCellsEntireRow

wdDeleteCellsShiftLeft

wdDeleteCellsShiftUp

删除指定数目的字符或单词。此方法返回一个 Long 值，该数值表明删除项的数目。如果删除失败，则返回的值为 0（零）。

expression.Delete(Unit, Count)

expression 必需。该表达式返回以上一个对象。

Unit Variant 类型，可选。所需删除的折叠区域或选定内容的单位。可以是下列 WdUnits 常量之一：wdCharacter（默认值）或 wdWord。

Count Variant 类型，可选。所需删除的单元的数目。若要删除某区域或选定内容之后的单元，请折叠该区域或选定内容并将此参数设置为正数；若要删除某区域或选定内容之前的单元，请折叠该区域或选定内容并将此参数设置为负数。

删除指定的对象。

expression.Delete(Index)

expression 必需。该表达式返回一个 ShapeNodes 对象。

Index Long 类型，必需。要删除的图形节点的数目。

删除指定的对象。

expression.Delete

expression 必需。该表达式返回“应用于”列表中的一个对象。

示例

本示例删除活动文档中第一个表格中的第一个单元格。

Sub DeleteCells()
    ActiveDocument.Tables(1).Cell(1, 1).Delete
End Sub

本示例选择并删除活动文档中的内容。

Sub DeleteSelection()
    ActiveDocument.Content.Select
    Selection.Delete
End Sub

本示例折叠选定内容并删除插入点后的两个单词。

Sub DeleteSelection2()
    ActiveDocument.Range(Start:=ActiveDocument.Paragraphs(3).Range.Start, End:=ActiveDocument.Paragraphs(6).Range.End).Select
    Selection.Collapse Direction:=wdCollapseStart
    Selection.Delete Unit:=wdWord, Count:=2
End Sub

本示例折叠 myRange 并删除插入点前的两个字符。

Sub DeleteRange()
    Dim myRange As Range
    Set myRange = Selection.Words(1)
    myRange.Collapse Direction:=wdCollapseStart
    myRange.Delete Unit:=wdCharacter, Count:=-2
End Sub

本示例删除活动文档的第一个单词。

Sub DeleteFirstWord()
    ActiveDocument.Words(1).Delete
End Sub

如果活动文档中存在名为“temp”的书签，则本示例删除该书签。

Sub DeleteBookmark()
    If ActiveDocument.Bookmarks.Exists(Name:="temp") Then
        ActiveDocument.Bookmarks(Name:="temp").Delete
    End If
End Sub

本示例删除 Sales.doc 中名为“Intro”的样式，将使用 Intro 样式的段落换成“正文”样式。

Sub DeleteStyle()
    Documents(Index:="Sales.doc").Styles _
        (Index:="Intro").Delete
End Sub