LetterContent 对象

Documents (Document) LetterContent

表示由“英文信函向导”创建的信函的元素。

使用 LetterContent 对象

用 GetLetterContent 方法或 CreateLetterContent 方法返回一个 LetterContent 对象。下列示例获得并显示活动文档中信函接受者的名字。

Set myLetterContent = ActiveDocument.GetLetterContent
MsgBox myLetterContent.RecipientName

下列示例用 CreateLetterContent 方法创建新的 LetterContent 对象，然后在该对象上使用 RunLetterWizard 方法。

Set myLetter = ActiveDocument _
    .CreateLetterContent(DateFormat:="July 11, 1996", _
    IncludeHeaderFooter:=False, _
    PageDesign:="C:\MSOffice\Templates\Letters & " _
        & "Faxes\Contemporary Letter.dot", _
    LetterStyle:=wdFullBlock, Letterhead:=True, _
    LetterheadLocation:=wdLetterTop, _
    LetterheadSize:=InchesToPoints(1.5), _
    RecipientName:="Dave Edson", _
    RecipientAddress:="100 Main St." & vbCr _
        & "Bellevue, WA 98004", _
    Salutation:="Dear Dave,", _
    SalutationType:=wdSalutationInformal, _
    RecipientReference:="", MailingInstructions:="", _
    AttentionLine:="", _
    Subject:="End of year report", CCList:="", ReturnAddress:="", _
    SenderName:="", Closing:="Sincerely yours,", _
    SenderCompany:="", _
    SenderJobTitle:="", SenderInitials:="", EnclosureNumber:=0)
ActiveDocument.RunLetterWizard _
    LetterContent:=myLetter, WizardMode:=True

说明

CreateLetterContent 方法创建 LetterContent 对象，但要用许多参数。要想只设置几个属性，则可用“New”关键词来创建新的、独立的 LetterContent 对象。下列示例创建一个 LetterContent 对象，设置它的一些属性，并且在此 LetterContent 对象上使用 RunLetterWizard 方法来运行信函向导（用预置值做为默认设置）。

Set myLetter = New LetterContent
With myLetter
    .AttentionLine = "Read this"
    .EnclosureNumber = 1
    .Letterhead = True
    .LetterheadLocation = wdLetterTop
    .LetterheadSize = InchesToPoints(2)
End With
Documents.Add.RunLetterWizard LetterContent:=myLetter, _
    WizardMode:=True

用 Duplicate 属性可复制 LetterContent 对象。以下示例获得活动文档中的信函元素并制作副本。该示例将副本分配给 aLetter，并将收件人姓名和地址重新设置为空字符串。RunLetterWizard 方法用于运行信函向导，可使用修订过的 LetterContent 对象中的值作为默认设置。

Set aLetter = ActiveDocument.GetLetterContent.Duplicate
With aLetter
    .RecipientName = ""
    .RecipientAddress = ""
End With
Documents.Add.RunLetterWizard LetterContent:=aLetter, _
    WizardMode:=True

SetLetterContent 方法插入文档中指定的 LetterContent 对象的内容。下列示例从活动文档中获得信函元素，改变信封用语，并用 SetLetterContent 方法更新活动文档以显示此变化。

Set myLetterContent = ActiveDocument.GetLetterContent
myLetterContent.AttentionLine = "Greetings"
ActiveDocument.SetLetterContent LetterContent:=myLetterContent