LinkToPrevious 属性

如果为 True，则指定页眉或页脚与前一节的相应页眉或页脚相链接。当一个页眉或页脚处于链接状态时，其内容与前面的页眉或页脚相同。Boolean 类型，可读写。

expression   必需。该表达式返回一个 HeaderFooter 对象。

说明

因为在默认情况下，LinkToPrevious 属性被设为 True，所以可以通过设置第一节的页眉、页脚和页码来为整个文档添加页眉、页脚和页码。例如，下面的示例将页码添加至活动文档每一节中的每一页。

ActiveDocument.Sections(1) _
    .Headers(wdHeaderFooterPrimary).PageNumbers.Add

LinkToPrevious 属性可以分别应用于每个页眉或页脚。例如，可将偶数页的页眉的 LinkToPrevious 属性设置为 True，而将偶数页的页脚设置为 False。

示例

本示例的第一部分创建一个有两节的新文档，第二部分为新文档的第一和第二节的偶数页和奇数页创建不同的页眉。

Documents.Add
With Selection
    For j = 1 to 4
        .TypeParagraph
        .InsertBreak
        .TypeParagraph
    Next j
End With
With ActiveDocument
    .Paragraphs(5).Range.InsertBreak Type:=wdSectionBreakNextPage
    .PageSetup.OddAndEvenPagesHeaderFooter = True
End With
With ActiveDocument.Sections(2)
    With .Headers(wdHeaderFooterPrimary)
        .LinkToPrevious = False
        .Range.InsertBefore "Section 2 Odd Header"
    End With
    With .Headers(wdHeaderFooterEvenPages)
        .LinkToPrevious = False
        .Range.InsertBefore "Section 2 Even Header"
    End With
End With
With ActiveDocument.Sections(1)
    .Headers(wdHeaderFooterPrimary) _
        .Range.InsertBefore "Section 1 Odd Header"
    .Headers(wdHeaderFooterEvenPages) _
        .Range.InsertBefore "Section 1 Even Header"
End With